Skip to content Skip to sidebar Skip to footer

Widget HTML #1

Cara Menghitung Kredit Barang di Excel Beserta Contohnya | Rumus Excel

Pekerja Kantoran khususnya Bagian Administrasi tentunya harus memiliki kemampuan dalam menghitung Aritmatik seperti Menghitung Angsuran dari Kredit Barang dengan menggunakan Rumus Logika di Excel. Dengan Menggunakan Rumus Excel untuk menghitung Kredit Barang mampu mempermudah kamu dalam menghitung Bunga, Angsuran Per minggu / Per Bulan, Uang Muka hingga Jumlah angsuran yang diperlukan.

Menghitung Kredit Barang dengan menggunakan Excel memerlukan beberapa unsur, Seperti : 

  • Id Pelanggan
  • Nama Pelanggan
  • Nama Barang
  • Harga
  • Uang Muka
  • Kredit Pokok
  • Lama Angsuran
  • Bunga
  • Angsuran
  • Pembayaran (Transfer/Tunai)
  • Tanggal Pembayaran
  • Keterangan
Sebagai Tenaga Administrasi kamu harus menguasai segala pengetahuan seputar Jual Beli serta perhitungan Aritmatik. Dengan menggunakan Rumus Excel nantinya semua unsurnya akan dihitung dengan baik kemudian Sistem pembayarannya bisa dipilih apa mau Tunai atau Kredit (angsuran). 

Dalam Pembelian Secara Kredit (Angsuran) Tentunya kamu harus menghitung Jumlah angsuran serta banyak bunga yang diberikan/Terima. Nah dengan menggunakan Ms Excel kamu bisa menghitung semua itu.

Untuk Membuat Aplikasi Menghitung Kredit Barang. Ikuti langkah-langkahnya dengan baik dan benar.

Contoh Aplikasi Menghitung Kredit Barang di Excel :

Cara Menghitung Angsuran Kredit Barang di Excel, Contohnya seperti bpada gambar berikut : 

Cara Menghitung Kredit Barang

Kemudian Untuk cara pembuatannya. Ikuti langkah-langkah di bawah ini, Perlu di perhatikan bahwa Setiap penggunaan Cells dalam excel akan mempengaruhi Rumus yang digunakan. Jadi Perhatikan dan ikuti langkah-langkahnya dengan baik.

Cara Menghitung Angsuran Kredit Barang di Excel : 

  1. Buka Ms Excel dan kemudian buatkan Worksheet baru
  2. Di Sheet 1, Ganti Nama Sheet Menjadi "DT_Pelangggan"
  3. Kemudian Buatkan Tabel seperti pada Gambar di bawah ini : 
    Contoh Data Pelanggan Kredit Barang
    Keterangan : 
    * Untuk Text di Kolomnya sesuaikan dengan Gambar di atas.
    * Buatlah Tabel dan kemudian Isi Tabelnya, Sebagai Contoh Perhatikan Gambar di atas.
    * Untuk membuat Borders pada tabel, Seleksi bagian Tabelnya kemudian Pergi ke Tab Home > Borders

  4. Untuk Bagian Kredit Pokok dan Angsuran (Minggu), Di isi dengan menggunakan Rumus.

    * Untuk Mengisi Bagian Kredit Pokok, Aktifkan Cells H4 Kemudian Masukan Rumus ini : 
    =IFERROR(F4-G4, " ")

    * Untuk Mengisi Bagian Angsuran (Minggu), Aktifkan Cells K4 kemudian masukan rumus ini :
    =IFERROR((H4+(J4*H4))/I4," ")

    Ket : 
    *** Setelah Memasukan Rumus Tekan ENTER
    ***Kemudian untuk mengisi Cells di bawahnya, Gunakan Fill Handle untuk menyalin Rumusnya tanpa harus mengetik ulang

  5. Kemudian Beri Nama Range B4:K13 dengan Nama "PELANGGAN" kemudian Range B4:B13 Dengan Nama "ID". Beri Nama dengan menggunakan Name Box. Perhatikan gambar di Bawah ini :  
    Cara menggunakan Name Box Excel
    Keterangan : 
    * Seleksi bagian Range nya kemudian Ketikan Nama di Name Box, Setelah itu Tekan Enter

  6. Tambah 1 Sheet lagi. Di Sheet 2, Ganti Nama Sheet 2 Menjadi "Angsuran Pkk"
  7. Di sheet 2 (angsuran pkk), Buatkan Tabel Angsuran Pokok Pelanggan. Perhatikan Gambar berikut : 
    Angsuran Kredit

  8. Agar Supaya Ketika kamu mengetikan ID pelanggan, Kemudian Bagian (Nama, Tgl, Lama Kredit, Bunga, Kredit Pokok dan Tgl Tempo) Terisi secara otomatis maka Gunakan Rumus-rumus berikut ini :
    ** Bagian Nama Pelanggan, Aktifkan Cells C4 Kemudian masukan rumus ini : 
    =IFERROR(INDEX(PELANGGAN,MATCH(C3,ID,0),2)," ")

    ** Bagian Tgl Peminjaman, Aktifkan Cells C5 Kemudian masukan rumus ini :
    =IFERROR(INDEX(PELANGGAN,MATCH(C3,ID,0),3)," ")
    Jika setelah mengetikan dan meng ENTER Rumus di atas hasilnya bukan berupa Tanggal, Maka Gunakan Number Format Short Date pada Cells Tersebut. caranya Aktifkan Cellsnya kemudian Pergi ke Tab Home > Number Format > Short Date

    ** Bagian Lama Kredit, Aktifkan Cells G3 Kemudian masukan rumus ini : 
    =IFERROR(INDEX(PELANGGAN,MATCH(C3,ID,0),8)," ")

    ** Bagian Bunga, Aktifkan Cells G4 kemudian masukan rumus ini :
    =IFERROR(INDEX(PELANGGAN,MATCH(C3,ID,0),9)," ")
    jika Setelah mengunakan rumus di atas hasilnya bukan berupa %, Maka Gunakan Format Number Percent Style. Caranya aktifkan Cells nya kemudian Pergi ke Tab Home > Percent Style di Grup Number Format

    **Bagian Kredit Pokok, Aktifkan Cells G5 kemudian masukan rumus ini :
    =IFERROR(INDEX(PELANGGAN,MATCH(C3,ID,0),7)," ")
    Untuk Menambahkan Symbol (Rp.) Gunakan Number Format Accounting dan kemudian Pilih Rp. Indonesia

  9. Selain bagian atasnya, Kamu juga bisa mengisi bagian tabelnya secara otomatis. Gunakan rumus-rumus berikut untuk mengisi bagian tabel nya : 
    ** Kolom Mingge ke-0, Cells B9
    =IFERROR(IF(OR(B8+1>$G$3,B8="0")," ",B8+1), " ")

    ** Kolom Angsuran Pokok, Cells C9
    =IFERROR(IF(OR(B9=0,B9>$G$3)," ",($G$5/$G$3))," ")

    **Kolom Bunga, Cells D9
    =IFERROR(IF(OR(B9=0,B9>$G$3)," ",($G$5*$G$4/$G$3))," ")

    ** Kolom Angsuran Per Minggu Bagian JML, Cells E9
    =IFERROR(IF(OR(B9=0,B9>$G$3)," ",C9+D9)," ")

    ** Kolom Angsuran Per minggu Bagian Tgl Tempo, Cells F9
    =IFERROR($C$5+(B9*7)," ")

    Ket :
    Untuk Mengisi Baris di Bagian Bawahnya dengan rumus, Gunakan Fill Handle agar kamu tidak mengetik ulang rumusnya.
    Contoh Hasilnya : 
    Laporan Kredit Angsuran Otomatis

  10. Buat Sheet baru, Kemudian beri nama Sheet nya "DT_Pembayaran
  11. Di sheet Tersebut, Buatlah Tabel sperti pada gambar di bawah ini : 
    Pembayaran angsuran Kredit

    Isi dengan rumus pada Bagian Nama Pelanggan dan Jml Angsuran. Sedangkan sisanya di isi input sendiri.
    ** Rumus Bagian Kolom Nama Pelanggan, Cells D4
    =IF(ISBLANK(B4)," ",VLOOKUP(B4,PELANGGAN,2,FALSE))

    ** Rumus Bagian Kolom Jml Angsuran, Cells E4
    =IF(ISBLANK(B4)," ",VLOOKUP(B4,PELANGGAN,10,FALSE))

    Untuk Mengisi Rumus di bagian bawahnya, Gunakan Fill Handle untuk mengisi rumus secara otomatis tanpa mengetik ulang.

  12. Untuk Mengisi Bagian Pembayaran Cells F4:F13, Dengan cara seleksi Cells Tersebut kemudian pergi ke Tab Data > Data Validation > Data Validation.


    Drop Down List Excel
    Kemudian Atur Data Validation nya seperti pada Gambar di atas.
    Hasilnya : 
    Drop Down List

  13. Setelah Itu, Inputkan Bagian ID Pelanggan, Tgl dan Pembayaran. Perhatikan Gambar berikut : 

  14. Selesai ...
Nah itu adalah cara untuk membuat aplikasi untuk menghitung Kredit Barang di Ms Excel. Tutorial ini menggunakan Rumus IFERROR, IF, Serta beberapa Rumus Lainnya. Untuk Teman-teman yang masih bingung bisa menanyakannya di kolom komentar. Namun Kamu bisa melakukannya dengan benar jika penempatan dan penggunaan Cells nya sama dengan di Tutorial ini.

Kemudian Jika rumus nya tidak Berfungsi maka ganti tanda " , " dengan tanda " ; ".

Pelajari Versi Video-nya disini dan dapatkan Password untuk Unprotect Sheet Excel-nya:

Baca Juga : Cara Membuat Slip Gaji di Excel | Contoh Slip Gaji Karyawan

Download File Aplikasi Kredit Barang (File xlsx) Disini.

Post a Comment for "Cara Menghitung Kredit Barang di Excel Beserta Contohnya | Rumus Excel"